トランジスタ回路

図11は, トランジスタ増幅とそのソースファイルです。 この回路で新たにトランジスタが登場しました。ご存知のようにトランジスタには足が3本あって, コレクタ, ベース, エミッタという名前が付いています。それぞれの足の名前と回路図記号の対応は同図中に書いてあります。

ソースファイルでトランジスタは「Q」という名前で始まることになっています。 それぞれの足の節点は, 「コレクタ」「ベース」「エミッタ」の順番で記述することになっています。

図 11: トランジスタ増幅回路; (a)回路図, (b)ソースファイル

(a)

(b)    

*Transistor amp., file_neme="amp.cir"
Vin		1 0		sin(0 0.01 100)
C1		1 2		4.7uF
R1		2 3		470k
R2		3 5		4.7k
Q1		3 2 0	QC1815		
C6		5 0		0.47uF
Vcc		5 0		9V
.OP
*****2SC1815 
.MODEL QC1815 NPN (IS=4E-14 BF=170 BR=3.6 VA=100 IK=0.25
+         RB=50 RC=0.76 CJC=4.8p CJE=12p TF=0.63n TR=25n)
.TRAN	0.01ms 5.1ms 0s 0.01ms
.END

この素子の特性(素子固有の定数)は, 「.MODEL」の行に記述してあります。２行に分かれていますので, そのまま入力してください。 ここで指定してある定数の意味は以下の通りです。

QC1815 NPN

「Q」はトランジスタを意味しており「C1815」は名前です。この名前は何でも良いのですが, ここではトランジスタ2SC1815 の特性を表現していますのでC1815という名前にしてあります。「NPN」はNPN型トランジスタを意味しています。

IS

飽和電流

BF

順方向電流増幅率$\beta _F$

BR

逆方向電流増幅率$\beta _R$

VA

順方向アーリー電圧 [V]

IK

順方向$\beta$高電流ロールオフに対する折れ曲がり点[A]

RB

ベース抵抗[$\Omega$]

RC

コレクタ抵抗[$\Omega$]

CJC

B-C間接合容量($V_{bc}=0$)[F]

CJE

B-E間接合容量($V_{be}=0$)[F]

TF

順方向通過時間(順方向トランジット時間)[s]

TR

逆方向通過時間(逆方向トランジット時間)[s]

そして2行目行頭の「＋」は「直前の行のつづき」という意味です。 これらの定数の意味は, ここでは割愛しますので電子回路で勉強してください。

「run」「show all」としてみてください。動作点の情報などが書かれています。意味は電子回路学で習いますので, 今は分からなくても良いです。

次に, 過渡解析で波形を見てましょう。「plot v(1)」で入力波形, 「plot v(3)」で出力波形がそれぞれ図12のように見れます。位相が180$^\circ$ずれており, それぞれの縦軸のスケールの違いに注意すればちゃんと電圧も増幅されていることが分かります。周波数や入力電圧を変えて, 遊んでみて下さい。ひょっとすると, 単純な正弦波だけでなく, トランジスタ回路の飽和現象等で波形の形が崩れたりするのが観察できるかもしれません。

図 12: 解析結果; (a)入力波形 - plot v(1), (b)出力波形 - plot v(3)

(a) (b)