gnuplot> plot [-pi:pi][-1.2:1.2] sin(x), 0.5*cos(x)と入力してみてください. 括弧内の数値で範囲を指定します.
- 最初の括弧が横軸で, -pi < x < piの範囲で描かれましたね. ここでpiは円周率π(=3.14159265...)です.
- 縦軸は2番目の括弧内で -1.2 < x < 1.2 の範囲で表示されています.
gnuplot> set xlabel "x [rad]" gnuplot> set ylabel "y" gnuplot> replot
- 1行目の「set xlabel」でx軸(横軸)の名前(タイトル)を指定,
- 2行目の「set ylabel」y軸(縦軸)の名前を指定しています.
- 3行目の「replot」 は 「先に描いたグラフを もう一度描きなさい」という命令です.
gnuplot> set xtics pi/2 gnuplot> set mxtics 2 gnuplot> replot
- set xticsで横軸の主目盛を指定します. x軸を見ると, π/2ごとに目盛が描かれています.
- mxticsは副目盛りを指定し, 主目盛と主目盛の間に入る 副目盛の数を指定します.
- 同様に, y軸の主目盛と副目盛は「ytics」と「mytics」で主目盛, 副目盛が設定できます.
- 横軸の桁数を減らしてみます.
gnuplot> set format x "%3.2f" gnuplot> replot
ここで%3.2fは, 表示の最小幅を3桁とし, 小数点以下を2桁とするという意味です. ちなみに指数表示したいときには「%e」あるいは「%E」を使います.円周率の倍数で表したい時には, 「%P」を用います.
gnuplot> set format x "%2.1P{/Symbol p}" gnuplot> replot円周率πは特殊文字{/Symbol p}で書けます. 他の特殊文字(ギリシア文字)はこちらを 参照ください.y軸も次のように桁数を指定するとかっこいいかも.
gnuplot> set format y "%2.1f" gnuplot> replot
- 凡例をいじってみます.
凡例を消したければ
gnuplot> set key off gnuplot> replot
凡例を表示するにはgnuplot> set key on gnuplot> replot
です.凡例をグラフの左上に移動します.
gnuplot> key left top gnuplot> replot
- 左右位置は「left」「right」「center」を
- 上下位置は「top」「bottom」「center」を
細かい位置調整が必要でしたら, 次のように画面の中の座標で指定できます.
gnuplot> set key at graph 0.25, 0.95
ここで, 次のようにして位置を指定します.- 形式:「at { graph | first | screen } (横方向), (縦方向)」
{ graph | first | screen } は「graph」, 「first」, 「screen」のいずれかを用いることを示し, - 「at first」はグラフの数値に対応した位置を指定
- 「at graph」はグラフ枠内を「0.0〜1.0」の範囲で指定
- screen はグラフの余白(マージン)を含めた全体を「0〜1」の範囲で指定
凡例の 線と名前の 順序を 入れ替える場合には
gnuplot> set key reverse gnuplot> replot
元に戻すには次のように入力します.gnuplot> set key noreverse gnuplot> replot
- 線の色や太さを変えたりできます.
gnuplot> plot [-pi,pi][-1.2:1.2] sin(x) with lines lt 5 lw 2 title "func 1", 0.5*cos(x) with points pt 1 title "func 2"
「with lines」や「with points」 を書くと次の指定が可能となります.(詳細は後で)- 「lt 番号」 の部分で線の種類を変更できます. (ltは「linetype」も可)
- 「lw 番号」も同様に線の幅を変更できます. (lw は「linewidth」も可)
- 「pt 番号」も同様にプロット点の種類を変更できます. (pt は「pointtype」も可)
- 「ps 値」で、プロット点の大きさ(少数も可)を指定できます. (psは「pointsize」も可)
また, 「title "何々"」 で凡例の名前 (ここでは「func 1」や「func 2」)を指定できます.
- 計算点の数を指定することもできます.
gnuplot> set samples 20 gnuplot> replot
「set samples」で, 点の数を調整できます. 上の例で, 20を「50」程度に増やすとなめらかになり, さらに増やすことも可能です.
ここまで, キーボードでコマンドを逐一入力する方法を紹介しました. この方法ではgnuplotを一旦終了してしまうと, 設定が全て初期化(消去)され てしまいます.
(4)スクリプトファイルでグラフを描く
命令を書き込んだファイル(スクリプトファイル)を作成・保存して, グラフを描かせることもできます. こうすることで, 何度でも繰り返して描画が可能となります. 次のようなスクリプトファイルを作成して, 適当な名前をつけて保存してください.(注意)Windowsの場合, 例えばデスクトップにgraphというフォルダーを作成(デスクトップ上でマウスを右クリック→[新規作成]→[フォルダ]→フォルダ名をgraphに変更)し，そこにスクリプトファイルを保存します. なお, フォルダ名は半角英数字でスペース等は入れないのが良いようです.
ここでは, ファイル名を「func.gnp」として説明します.
# sin, cos をプロットする gnuplot スクリプト
# 2017/05/11 K.Yamamoto
#
set xlabel "x [rad]"
set ylabel "y"
set xtics pi/2
set mxtics 2
set format x "%3.2P{\Symbol p}"
set format y "%2.1f"
set key at graph 0.25, 0.95
set samples 20
plot [-pi:pi][-1.2:1.2] sin(x) with lines linetype 3 title "func 1",\
0.5*cos(x) with points pointtype 1 title "func 2"
pause -1
これまでと違う点は次の3点です.
- 最初の3行はコメントです. (「#」から行末までコメントとみなされます)
- plotの行はこれまでどおり１行で記入しても良いのですが,
可読性を良くするために２行で記入してあります.
次の行に続くことをあらわすために行末に「\」バックスラッシュ
(環境によっては円マーク(¥)に見えるかも)を記入します.
(その後ろにスペースなどを入れてはいけませんが, 次の行頭のスペースなどは問題ありません) - 「pause -1」で一時停止させます. (これがなければ一瞬でグラフが消えてしまいます)
- 既にgnuplotが立ち上がっていれば, gnuplot内で次のスクリプトを実行させる.
gnuplot> call "func.gnp"
- UNIXのターミナル(LXTerminalなど)上でgnuplotが終了した状態で次のように入力する.
> gnuplot func.gnp
- Windowsの場合には, スクリプトファイルをgnuplot画面にドラッグするか, 「ファイル」--> 「読み込み」でも実行できます.
pause より先に進むには, グラフ上でキーボードの「q」を押下するか, ターミナル上でリターンキーを押下します.
スクリプトを中止するには, ターミナル上で ctrl-C (Ctrlキーを押しながらcキーを押す)とします.
(5)図の保存
描いた図を保存して論文等に利用することも可能です. 論文等にグラフを利用する場合, 図の拡大縮小してもキレイなベクトル形式が好都合なので，次の組み合わせをお勧めします.
- Wordの場合: emf
- 描画ソフトInkscapeの場合: svg
- LaTeXの場合: eps
gnuplotではこれから説明する命令を実行することで, これら出力形式(terminal)とファイル名をを指定できます. ただ, 線や点の種類がterminalによってかわってしまうので注意が必要です. どの形式も次の手順になります. これらはgnuplotに直接命令してもよいし，スクリプトファイルに書いてもよいです．
- 保存形式を指定 (set terminal)
- 保存ファイル名を指定 (set output)
- 指定したファイルを作成(再描画) (replot)
- emf形式(Enhanced Metafile Format の略で, 多くのWindowsアプリで使用可)の例
set terminal emf enhanced font "Times,20" set output "hoge.emf" replot
- 「set terminal emf enhanced」の部分で, emf形式を指定し, 斜体やギリシヤ文字などの拡張文字を使用可と指定
- 「font "Times,20"」の部分で, フォント(Times)とフォントサイズ(20pt)を指定
- 「set output "hoge.emf"」の部分で, hoge.epsという出力ファイル名を指定
- 「replot」で, 先に描いたグラフを再度描く
- Inkscape (SVG: Scalable Vector Graphics Format)形式の例
set terminal svg enhanced font "Times,20" set output "hoge.svg" replot
ベクター形式ですので, 拡大・縮小で画質が劣化しません. hoge.svgをinkscapeで編集して，その結果をemf形式などで保存できます. - eps形式の例 (LaTeXを使う人へ)
set terminal postscript eps enhanced font "Times,20" clip set output "hoge.eps" replot
これらをまとめたスクリプトファイル(func-save.gnp)を実行してみてください. hoge.emfファイルと hoge.svgファイルが生成されていると思います．
なお, 出力形式を最初のディスプレイ(wxt)に戻して，画面上でグラフを確認するのは次の命令です.
set terminal wxt replot
BACK(gnuplot)| MENU(ページトップ)| NEXT(測定データのプロット)|
Ken-ichi Yamamoto
e-mail: yamamoto@eee.u-ryukyu.ac.jp